分支与循环

复习

汇编器：通过两遍扫描，把符号汇编成机器码
高级语言：再加一层：从“控制机器”转向“描述问题”
变量、类型与表达式：名字如何代表数据，表达式如何变成运算

TL;DR

判断落到机器上，是“比较 + 条件跳转”
比较的结果记在状态标志里，跳转指令根据标志决定改不改 PC
循环就是“往回跳”，再加上一个“该不该停下”的判断
顺序、选择、循环三种结构，构成了所有程序

正文

　　到现在为止，我们的程序只会一条道走到黑。可现实里更像这样：如果分数及格就显示“通过”；把 1 到 100 加起来；只要还没做完就再来一遍。要表达这些，程序得学会拐弯和回头。

判断：比较加跳转

　　先看最简单的一句：

if x > y:
    max = x
else:
    max = y

　　人一眼就懂，机器却只会计算和跳转。它怎么知道 x 大于 y？

　　办法还是计算：把两个数相减。如果 x - y 是正数，说明 x 更大；是 0，说明相等；是负数，说明 x 更小。这一步相减，就叫比较。

　　我们把比较写成一条指令 CMP：它做减法、设置状态标志，但 不保存减法结果 ——我们关心的不是差是多少，而是差的正负。然后，再由跳转指令去看标志：

      LOAD A, [x]
      LOAD B, [y]
      CMP  A, B
      JGT  then        ; 若 x > y，跳到 then
      MOV  R, B        ; 否则 max = y
      STORE [max], R
      JMP  end
then: MOV  R, A        ; max = x
      STORE [max], R
end:  HALT

　　MOV 是“把一个寄存器里的值搬到另一个寄存器”。这里的 JGT 是“大于则跳转”。除了它，还有一批类似的指令：JZ（等于 0 则跳）、JN（为负则跳）、JLE（小于等于则跳）……名字不用记， 它们全都是先看标志，再决定改不改 PC。

　　顺带一提，前面几章那个 Z 标志，就是在这类地方派上用场的：ALU 负责产生标志，跳转指令负责根据标志选路。

循环：往回跳

　　再看“把 1 到 n 加起来”：

sum = 0
i = 1
while i <= n:
    sum = sum + i
    i = i + 1

　　翻译成汇编：

      ; 这里假设 sum、i、n、one 都已就位
loop: LOAD A, [i]
      LOAD B, [n]
      CMP  A, B
      JGT  done         ; i > n 时结束
      LOAD A, [sum]
      LOAD B, [i]
      ADD  R, A, B
      STORE [sum], R    ; sum = sum + i
      LOAD A, [i]
      LOAD B, [one]
      ADD  R, A, B
      STORE [i], R      ; i = i + 1
      JMP  loop         ; 回到开头
done: HALT

　　对照着看：while 的判断变成“比较 + 不满足就跳出”；循环体照抄；最后一条 JMP loop 把 PC 改回开头，于是这几行被反复执行。

　　循环，本质上就是“往回跳”。 只不过每次跳之前，都要问一句“还该继续吗”。